next »

[Enrico S.]

Hi,
If I'm not in error, in XML serialization field names and fields order must match in both XML node structure and Genero record structure,  while in JSON serialization these match are not required.
Is it a choice ?
Could we expect in a future release these XML constraints to be overcome ?

Best Regards.
Enrico

[Reuben B.]

There are some options that relax the requirements, see the two ignoreunknown attributes here http://4js.com/online_documentation/fjs-fgl-manual-html/#fgl-topics/r_gws_XmlSerializer_option_flags.html as well as attributes such as XMLOptional  that may help you.

However if your question is more about the order, and you are asking as with an example like the following ...

Code

IMPORT util
IMPORT xml
MAIN
DEFINE r RECORD
    field1 STRING,
    field2 STRING
END RECORD
DEFINE d1,d2 xml.DomDocument
 
    -- JSON 
    INITIALIZE r TO NULL
    CALL util.JSON.parse('{"field1":"value1","field2":"value2"}',r)
    DISPLAY r.field1, r.field2
    -- Swap order around, can still parse
    INITIALIZE r TO NULL
    CALL util.JSON.parse('{"field2":"value2","field1":"value1"}',r)
    DISPLAY r.field1, r.field2
 
    --XML
    INITIALIZE r TO NULL
    LET d1 = xml.DomDocument.create()
    CALL d1.loadFromString("<root><field1>value1</field1><field2>value2</field2></root>")
    CALL xml.Serializer.DomToVariable(d1.getDocumentElement(),r)
    DISPLAY r.field1, r.field2
 
    -- Swap order around, cannot parse
    INITIALIZE r TO NULL
    LET d2 = xml.DomDocument.create()
    CALL d2.loadFromString("<root><field2>value2</field2><field1>value1</field1></root>")
    CALL xml.Serializer.DomToVariable(d2.getDocumentElement(),r)
    DISPLAY r.field1, r.field2
 
END MAIN

why you can swap the order for JSON and it will still parse, but if you swap the order for XML it won't parse. 

I think the answer to this lies by using the XMLALL attribute http://4js.com/online_documentation/fjs-fgl-manual-html/#fgl-topics/c_gws_XML_attribute_XMLAll.html

By changing the above example to have

Code

DEFINE r RECORD ATTRIBUTES(XMLAll)
 

then it runs which I suspect is what you are after.

Why do you need the option, and why does it not work by default, note that with a JSON string, the element name is unique, whilst the XML Node Name is not necessarily unique

Reuben

[Enrico S.]

Hi, Reuben. I understand.
The "why" is that in past third-party developers was asking me to ignore fields order (they was manually serializing SOAP messages).
Now I simply wanted to go in deep to this argument and I was asking for your point of view.
But I was not considering the uniqueness of JSON node names against XML.
Thanks a lot for your answer.
Enrico.

[Rene S.]

Some fun:

Code

OPTIONS SHORT CIRCUIT
IMPORT util
 
MAIN
    DEFINE r RECORD
        field1 STRING,
        field2 STRING
    END RECORD
    DEFINE jo util.JSONObject
 
    LET jo = xml2json(
            "<root><field1>value1a</field1><field2>value2a</field2></root>")
    CALL jo.toFGL(r)
    DISPLAY r.*
 
    LET jo = xml2json(
            "<root><field2>value2b</field2><field1>value1b</field1></root>")
    CALL jo.toFGL(r)
    CALL jo.toFGL(r)
    DISPLAY r.*
END MAIN
 
FUNCTION xml2json(xml STRING) RETURNS util.JSONObject
    DEFINE doc om.DomDocument 
    DEFINE root, node, chars om.DomNode
    DEFINE jo util.JSONObject
 
    LET doc = om.DomDocument.createFromString(xml)
    LET root = doc.getDocumentElement()
    LET jo = util.JSONObject.create()
    LET node = root.getFirstChild()
    WHILE node IS NOT NULL
        IF (chars := node.getFirstChild()) IS NOT NULL
            AND chars.getTagName() == "@chars" THEN
            CALL jo.put(node.getTagName(), chars.getAttribute("@chars"))
        END IF
        LET node = node.getNext()
    END WHILE
    RETURN jo
END FUNCTION
 

Code:

$ fglcomp test && fglrun test
value1avalue2a
value1bvalue2b

[Enrico S.]

Nice.
Not so well explained in manuals the meaning of @chars attribute name of Text nodes (it is new for me), but searching in deep from your sample it is possible to understand.
Every time I ask something, you let me know a further small brick.
Thanks again.
Enrico

[Sebastien F.]

Hello Enrico,

Your suggestions to improve the documentation are welcome.

Please use the feedback facility when something is missing or unclear.

We talk about the @chars attribute and tagname in the following pages:

    http://4js.com/online_documentation/fjs-fgl-manual-html/#fgl-topics/c_fgl_ClassDomNode_getAttribute.html
    http://4js.com/online_documentation/fjs-fgl-manual-html/index.html#fgl-topics/c_fgl_ClassDomDocument_createChars.html

However, I agree that it is missing here:

    http://4js.com/online_documentation/fjs-fgl-manual-html/#fgl-topics/c_fgl_ClassDomNode_getTagName.html

Do you expect something else?

Seb